Contents

[Data Set Up 2](#_Toc109897755)

[Usages 3](#_Toc109897756)

[Starter Code 3](#_Toc109897757)

[Exercise 1 4](#_Toc109897758)

[Exercise 2 5](#_Toc109897759)

[Exercise 3 6](#_Toc109897760)

[Exercise 4 7](#_Toc109897761)

[Exercise 5 8](#_Toc109897762)

[Exercise 6 9](#_Toc109897763)

[Summarization 10](#_Toc109897764)

[Starter Code 10](#_Toc109897765)

[Exercise 7 11](#_Toc109897766)

[Exercise 8 12](#_Toc109897767)

[Styling 13](#_Toc109897768)

[Starter Code 13](#_Toc109897769)

[Exercise 9 14](#_Toc109897770)

[Exercise 10 15](#_Toc109897771)

[Answer Key 16](#_Toc109897772)

Proc Report Step by Step

In this hands-on training session, you will learn to create PROC REPORT code for multiple report types. Each concept and report type will be explained, then you will spend time writing code to create your own report. SESUG will not be providing laptops. Please bring your own device so you can get the most out of this training opportunity.

# Data Set Up

The Ames Housing data will be used for all exercises during the workshop. Follow these instructions for creating the data and corresponding formats.

1. Locate the createdata.sas program.
2. Download the file and open it in your preferred SAS environment.
3. Run the program. The data and formats are stored in the Work directory.
4. Submit the following OPTIONS and TITLE statements.

options missing=**0**;

title1 'Ames Housing';

These are the variables that will be utilized frequently during the workshop.

|  |  |
| --- | --- |
| Key Variables | Formats |
| Bldg\_type | $bldg\_type |
| Electrical | $electrical |
| Sale\_type | $sale\_type |
| Yr\_sold |  |
| Saleprace | Dollar15.2 |
| Gr\_liv\_are | 8. |

# Usages

DISPLAY

Proc Report prints out the value from your data set. Any character variables from your data set automatically defaults to being display.

GROUP

Instructs Proc Report to order the table by the value from the incoming data set and to consolidate, or collapse, by those values.

ORDER

Instructs Proc Report to order by those values.

COMPUTED

Indicates a brand-new column that is not on your data set.

ANALYSIS

In Proc Report all numeric values default to being analysis variables, so you don’t have to actually say that it is an analysis variable. Programmers find it handy to specify analysis so that they know exactly how that variable is being used. Also, on the define statement for analysis variables you can specify the statistic that you want it to be. It defaults to being sum but you can use mean, minimum, kurtosis if you want.

ACROSS

Its values become column headers.


## Starter Code

**proc** **report** data=ameshousing;

where yr\_sold=**2010**;

column bldg\_type electrical n saleprice;


## Exercise 1




## Exercise 2




## Exercise 3




## Exercise 4



## Exercise 5



## Exercise 6



# Summarization

Create summary rows at specified locations. We define the location as either before or after, which means the summary row is placed either at the top of a section or at the bottom of a section.

BREAK

Requires a group or order variable along with location. Summarization occurs for all observations with that value of group/order variable.

RBREAK

Only requires a location. It is a report-level summarization, so it is for all observations in the data set.

## Starter Code

**proc** **report** data=ameshousing;

format bldg\_type $bldg\_type. sale\_type $sale\_type.;

column yr\_sold bldg\_type sale\_type saleprice gr\_liv\_area;

## Exercise 7



## Exercise 8



# Styling

[Style Attributes documentation](https://go.documentation.sas.com/doc/en/pgmsascdc/v_028/odsproc/n1b4339kviqrrcn1lt1lbm68e8xx.htm)

STYLE(<location>)= in PROC REPORT and/or DEFINE statements

[Location documentation](https://go.documentation.sas.com/doc/en/pgmsascdc/v_028/proc/p14xegao6xt0xnn1865r422tpytw.htm)

* CALLDEF
* COLUMN
* HEADER
* LINES
* SUMMARY

Example:

define city / style(header)={font\_weight=bold};

CALL DEFINE

Sets the value of an attribute for a particular column or row. A CALL DEFINE statement is only valid within a compute block. [Documentation](https://go.documentation.sas.com/doc/en/pgmsascdc/v_028/proc/n1b1be5822k8nnn1s1ucv8fvpg3d.htm)

CALL DEFINE (column-id | \_ROW\_, 'attribute-name', value);

Column-id: character literal, character expression, numeric literal, numeric expression, \_cn\_, \_col\_

Attribute-name: format, url, style, style/merge

Example:

call define(\_col\_,'style','style={foreground=red}');

call define('price.sum','style','style={background=blue}');

## Starter Code

**proc** **report** data=ameshousing;

where yr\_sold=**2010**;

format bldg\_type $bldg\_type. sale\_type $sale\_type.;

column bldg\_type sale\_type saleprice gr\_liv\_area;

## Exercise 9



## Exercise 10

**proc** **format**;

value size

low-**500** = 'red'


**500**-**700** = 'orange'

**700**-**1000** = 'yellow'

**1000**-**1500** = 'lightgreen'

**1500**-high = 'green';

**run**;



# Answer Key

options missing=**0**;

title1 'Ames Housing';

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

USAGES

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

title2 'Usage';

\*display, analysis - Exercise 1;

title3 'Display and Analysis';

**proc** **report** data=ameshousing;

where yr\_sold=**2010**;

column bldg\_type electrical n saleprice;

define bldg\_type / format=$BLDG\_TYPE.;

define electrical / format=$ELECTRICAL.;

define n / 'Units Sold';

define saleprice / 'Total Sales' format=dollar15.2;

**run**;

\*order, analysis - Exercise 2;

title3 'Order and Analysis';

**proc** **report** data=ameshousing;

where yr\_sold=**2010**;

column bldg\_type electrical n saleprice;

define bldg\_type / order format=$BLDG\_TYPE.;

define electrical / order format=$ELECTRICAL.;

define n / 'Units Sold';

define saleprice / 'Total Sales' format=dollar15.2;

**run**;

\*group, analysis - Exercise 3;

title3 'Group and Analysis';

**proc** **report** data=ameshousing;

column bldg\_type electrical n saleprice;

define bldg\_type / group format=$BLDG\_TYPE.;

define electrical / group format=$ELECTRICAL.;

define n / 'Units Sold';

define saleprice / 'Total Sales' format=dollar15.2;

**run**;

\*alias - Exercise 4;

title3 'Alias';

**proc** **report** data=ameshousing;

column bldg\_type electrical n saleprice saleprice=sales1;

define bldg\_type / group format=$BLDG\_TYPE.;

define electrical / group format=$ELECTRICAL.;

define n / 'Units Sold';

define saleprice / 'Total Sales' format=dollar15.2;

define sales1 / mean 'Avg Sales' format=dollar15.2;

**run**;

\*computed - Exercise 5;

title3 'Computed';

**proc** **report** data=ameshousing;

column bldg\_type electrical n saleprice sales1;

define bldg\_type / group format=$BLDG\_TYPE.;

define electrical / group format=$ELECTRICAL.;

define n / 'Units Sold';

define saleprice / 'Total Sales' format=dollar15.2;

define sales1 / computed 'Computed Avg Sales' format=dollar15.2;

compute sales1;

sales1 = saleprice.sum / n;

endcomp;

**run**;

\*across - Exercise 6;

title3 'Across';

**proc** **report** data=ameshousing;

column bldg\_type electrical yr\_sold,(n saleprice);

define bldg\_type / group format=$BLDG\_TYPE.;

define electrical / group format=$ELECTRICAL.;

define yr\_sold / across;

define n / 'Units Sold';

define saleprice / 'Total Sales' format=dollar15.2;

**run**;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

SUMMARIZATION

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

title2 'Summarization';

\*break and rbreak - Exercise 7;

title3 'BREAK and RBREAK';

**proc** **report** data=ameshousing;

format bldg\_type $bldg\_type. sale\_type $sale\_type.;

column yr\_sold bldg\_type sale\_type saleprice gr\_liv\_area;

define yr\_sold / group;

define bldg\_type / group;

define sale\_type / group;

define saleprice / mean format=dollar15.2;

define gr\_liv\_area / mean format=**8.**;

break after yr\_sold / summarize;

break after bldg\_type / summarize;

rbreak after / summarize;

**run**;

\*add summary text - Exercise 8;

title3 'Summary text';

**proc** **report** data=ameshousing;

format bldg\_type $bldg\_type. sale\_type $sale\_type.;

column yr\_sold bldg\_type sale\_type saleprice gr\_liv\_area;

define yr\_sold / group;

define bldg\_type / group;

define sale\_type / group;

define saleprice / mean format=dollar15.2;

define gr\_liv\_area / mean format=**8.**;

break after yr\_sold / summarize;

break after bldg\_type / summarize;

rbreak after / summarize;

compute after bldg\_type;

bldg\_type = 'Bldtot';

endcomp;

compute after;

bldg\_type = 'G tot';

endcomp;

**run**;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

STYLING

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\*add style formatting to summary rows - Exercise 9;

title3 'Summary rows style formatting';

**proc** **report** data=ameshousing;

where yr\_sold=**2010**;

format bldg\_type $bldg\_type. sale\_type $sale\_type.;

column bldg\_type sale\_type saleprice gr\_liv\_area;

define bldg\_type / group;

define sale\_type / group;

define saleprice / mean format=dollar15.2;

define gr\_liv\_area / mean format=**8.**;

break after bldg\_type / summarize;

rbreak after / summarize;

compute after bldg\_type;

bldg\_type = 'Total';

call define('saleprice.mean','style','style={font\_weight=bold}');

call define('gr\_liv\_area.mean','style','style={font\_weight=bold}');

endcomp;

compute after;

bldg\_type = 'GTotal';

call define(\_row\_,'style','style={font\_weight=bold background=lightblue}');

endcomp;

**run**;

\*use a format - Exercise 10;

title3 'Use STYLE= and a format';

**proc** **format**;

value size

low-**500** = 'red'

**500**-**700** = 'orange'

**700**-**1000** = 'yellow'

**1000**-**1500** = 'lightgreen'

**1500**-high = 'green';

**run**;

**proc** **report** data=ameshousing;

where yr\_sold=**2010**;

format bldg\_type $bldg\_type. sale\_type $sale\_type.;

column bldg\_type sale\_type saleprice gr\_liv\_area;

define bldg\_type / group;

define sale\_type / group;

define saleprice / mean format=dollar15.2;

define gr\_liv\_area / mean format=**8.** style(column)=[background=size.];

break after bldg\_type / summarize;

rbreak after / summarize;

compute after bldg\_type;

bldg\_type = 'Total';

call define('saleprice.mean','style','style={font\_weight=bold}');

call define('gr\_liv\_area.mean','style','style={font\_weight=bold}');

endcomp;

compute after;

bldg\_type = 'GTotal';

call define(\_row\_,'style','style={font\_weight=bold background=lightblue}');

endcomp;

**run**;